Автор Тема: Вызов транзакции (проги) со своей и последующий забор данных (Прочитано 4813 раз)

Паганель · « : Март 13, 2009, 05:08:00 pm »

Хотелось бы вызвать ту же mb5b и после того как она отработает, считать данные с ее таблички в которую она сохраняет.

по аналогии с ASSIGN ('(SAPMM07M)xmseg[]') TO <fs_mseg>.

для RM07MLBD_FORM_02
G_T_BELEGE1

не подскажете возможно ли это, и как это сделать?

Паганель · « **Ответ #1 :** Март 13, 2009, 05:10:16 pm »

Откуда начать копать? Это типа продолжение темы http://sapforum.biz/index.php/topic,543.new.html

Uukrul · « **Ответ #2 :** Март 13, 2009, 05:27:52 pm »

В общем случае задача не имеет решения, так как вызов ASSIGN ('(SAPMM07M)xmseg[]') TO <fs_mseg> работает в контексте транзакции из экзита и к этому моменту данные есть в памяти. В твоем же случае ситуация такая что программа уже отработала и локальных и прочих данных уже нет. Для MB51 например при правильном вызове эта транзакция сохраняет данные через IMPORT TO MEMORY поэтому ее результат можно считать. Можно ли для MB5B такое же... ну при беглом просмотре кода, ничего похожего не найдено.

Паганель · « **Ответ #3 :** Март 13, 2009, 05:39:35 pm »

Жаль конечно

Тогда переходим к обсуждению темы про подлом стандартных транзакций ....тока где-то нету ее

Паганель · « **Ответ #4 :** Март 13, 2009, 05:40:41 pm »

Цитата: Паганель от Март 13, 2009, 05:39:35 pm

Жаль конечно
Тогда переходим к обсуждению темы про подлом стандартных транзакций ....тока где-то нету ее

А ее перенесли сюда, ну что же тогда тут и продолжаем

Uukrul · « **Ответ #5 :** Март 13, 2009, 05:48:16 pm »

Цитата: Паганель от Март 13, 2009, 05:39:35 pm

Жаль конечно
Тогда переходим к обсуждению темы про подлом стандартных транзакций ....тока где-то нету ее

Называется SE38 а там копируешь стандартную программу в свою и делаешь с ней чего хочешь, вот тебе и все подлом...

Паганель · « **Ответ #6 :** Март 13, 2009, 05:56:40 pm »

Цитата: Uukrul от Март 13, 2009, 05:48:16 pm

Называется SE38 а там копируешь стандартную программу в свою и делаешь с ней чего хочешь, вот тебе и все подлом...

Это то же решение, правда один недостаток: если будут обновления (изменения логики выбора, исправления ошибок), и они затронут mb5b, твою прогу они не затронут.

Dmitriy · « **Ответ #7 :** Март 13, 2009, 05:57:56 pm »

Есть еще такой момент, разобраться в отчете и уже написать в своем все нужные выборки, т.е. безо всяких вызовов делаешь свой собственный отчет "с нуля".

Dmitriy · « **Ответ #8 :** Март 13, 2009, 05:59:01 pm »

Цитата: Паганель от Март 13, 2009, 05:56:40 pm

Это то же решение, правда один недостаток: если будут обновления (изменения логики выбора, исправления ошибок), и они затронут mb5b, твою прогу они не затронут.

Поэтому нужно разбираться в mb5b.

Паганель · « **Ответ #9 :** Март 13, 2009, 06:01:52 pm »

Цитата: Dmitriy от Март 13, 2009, 05:59:01 pm

Поэтому нужно разбираться в mb5b.

Не понял ..... что ты имел ввиду?

Dmitriy · « **Ответ #10 :** Март 13, 2009, 06:06:22 pm »

Тебе же в своем отчете нужны данные mb5b? Вот если разобраться в коде и написать в своем отчете его, то и получишь нужные тебе результаты. Можно готовое вставлять, можно п/п использовать, даже не копируя. Варианты, в общем, есть!

Uukrul · « **Ответ #11 :** Март 14, 2009, 11:01:59 am »

Цитата: Паганель от Март 13, 2009, 05:56:40 pm

Это то же решение, правда один недостаток: если будут обновления (изменения логики выбора, исправления ошибок), и они затронут mb5b, твою прогу они не затронут.

Если ты сломаешь любую стандартную транзакцию, то обновления ей уже не грозят...

Паганель · « **Ответ #12 :** Март 14, 2009, 12:21:16 pm »

Цитата: Uukrul от Март 14, 2009, 11:01:59 am

Если ты сломаешь любую стандартную транзакцию, то обновления ей уже не грозят...

Я имел ввиду расширение, т.е. UserExit или что-то подобное ....

Dmitriy · « **Ответ #13 :** Март 14, 2009, 01:14:01 pm »

Цитата: Паганель от Март 14, 2009, 12:21:16 pm

Я имел ввиду расширение, т.е. UserExit или что-то подобное ....

Для подобного вида транзакций это можно сделать только через неявную точку расширения, где воткнуть EXPORT, а потом в своем отчете IMPORT.

Uukrul · « **Ответ #14 :** Март 14, 2009, 04:33:30 pm »

Ну где-то так как написал тут: http://sapforum.biz/index.php/topic,546.0.html

Паганель · « **Ответ #15 :** Март 25, 2009, 01:21:30 pm »

Цитата: Uukrul от Март 13, 2009, 05:27:52 pm

Для MB51 например при правильном вызове эта транзакция сохраняет данные через IMPORT TO MEMORY поэтому ее результат можно считать. Можно ли для MB5B такое же... ну при беглом просмотре кода, ничего похожего не найдено.

То есть речь идет об SUBMIT *** AND RETURN EXPORTING LIST TO MEMORY?

Цитата: Uukrul от Март 13, 2009, 05:27:52 pm

ну при беглом просмотре кода, ничего похожего не найдено.

А по каким критериям определяется можно ли использовать EXPORTING LIST TO MEMORY ?

Кстати вот нашел (для другой транз. правда) http://www.sapnet.ru/viewtopic.php?t=1893&highlight=syucomm+list

Uukrul · « **Ответ #16 :** Март 25, 2009, 01:33:55 pm »

Ну так экспорт через память можно только тогда, когда формирование отчета выполняется через операторы WRITE, т.е. абап списком. Если, же отчет ALV, то и экспортировать нечего. В твоем случае MB5B таки можно экспортировать в память.

Паганель · « **Ответ #17 :** Март 25, 2009, 01:37:57 pm »

Ураааааааааа .........

Паганель · « **Ответ #18 :** Март 25, 2009, 05:52:09 pm »

Следующий вопрос: может кто знает как потом значения вытянуть после того как експортировали в память?
Нашел только ф-ию LIST_FROM_MEMORY но .....

Делаю так:

Код: [Выделить]

FORM call_mb5b
      USING
             zwerks LIKE  z_mkpf_mseg-werks
             zmatnr LIKE mara-matnr
             bdate_rest TYPE sy-datum.
           "  edate_rest TYPE sy-datum.
*      CHANGING
*        brest_menge TYPE z_mkpf_mseg-menge " остаток на начало
*        brest_dmbtr TYPE z_mkpf_mseg-dmbtr
*        erest_menge TYPE z_mkpf_mseg-menge " остаток на конец
*        erest_dmbtr TYPE z_mkpf_mseg-dmbtr.

  SUBMIT RM07MLBD
  WITH MATNR = zmatnr
  WITH WERKS = zwerks
  WITH BUDAT = bdate_rest
  EXPORTING LIST TO MEMORY AND RETURN.

  DATA: ABAPLIST LIKE ABAPLIST OCCURS 0.
  CALL FUNCTION 'LIST_FROM_MEMORY'
  TABLES
    LISTOBJECT = ABAPLIST
  EXCEPTIONS
    NOT_FOUND = 1
    OTHERS = 2.

*if sy-batch = space.
  CALL FUNCTION 'DISPLAY_LIST'
  EXPORTING
    FULLSCREEN = 'X'
  IMPORTING
    USER_COMMAND = SY-UCOMM
  TABLES
    LISTOBJECT = ABAPLIST
  EXCEPTIONS
    EMPTY_LIST = 1
    OTHERS = 2.
ENDFORM.

Uukrul · « **Ответ #19 :** Март 25, 2009, 06:00:07 pm »

Цитата: Паганель от Март 25, 2009, 05:52:09 pm

Нашел только ф-ию LIST_FROM_MEMORY но .....

Что но?

Паганель · « **Ответ #20 :** Март 25, 2009, 09:02:19 pm »

Что-что

, таким образом как в примере выше, я могу просто вывести ALV List такой же как и в mb5b

Uukrul · « **Ответ #21 :** Март 25, 2009, 09:34:08 pm »

А дальше типа так, получаешь вменяемый текст и из него пытаешься выцепить нужные тебе данные...

Код: [Выделить]

DATA: BEGIN OF lt_list OCCURS 1,
  str(1000) TYPE c,
END OF lt_list.

CALL FUNCTION 'LIST_TO_ASCI'
* EXPORTING
*   LIST_INDEX               = -1
*   WITH_LINE_BREAK          = ' '
* IMPORTING
*   LIST_STRING_ASCII        =
*   LIST_DYN_ASCII           =
 TABLES
   listasci                 = lt_list
   listobject               = abaplist
 EXCEPTIONS
   empty_list               = 1
   list_index_invalid       = 2
   OTHERS                   = 3.

Uukrul · « **Ответ #22 :** Март 25, 2009, 09:37:40 pm »

Парсинг строк отчета думаю сам напишешь? Если задавать как у тебя завод, материал... то там вообще будет все просто, с вытаскиванием запаса.

Паганель · « **Ответ #23 :** Март 25, 2009, 11:39:23 pm »

Цитата: Uukrul от Март 25, 2009, 09:37:40 pm

Парсинг строк отчета думаю сам напишешь? Если задавать как у тебя завод, материал... то там вообще будет все просто, с вытаскиванием запаса.

Сложновато будет, нет какого-то у тебя примерчика, да и не понятно как к строке достучатся, там как я понял какая то табличка непонятной структуры

Uukrul · « **Ответ #24 :** Март 26, 2009, 12:00:03 am »

Табличка очень понятной структуры... что видно из аттачмента. Получить данные можно где-то так... при условии что задаешь поиск по материал/завод, то все будет работать.

Код: [Выделить]

DATA: l_start LIKE mseg-menge,
      l_plus LIKE mseg-menge,
      l_minus  LIKE mseg-menge,
      l_end LIKE mseg-menge,
      l_index LIKE sy-tabix.
LOOP AT lt_list.
  IF lt_list-str(8) = 'Запас на'.
    l_start = lt_list-str+20(25).

    l_index = sy-tabix + 1.
    READ TABLE lt_list INDEX l_index.
    l_plus = lt_list-str+20(25).

    l_index = sy-tabix + 1.
    READ TABLE lt_list INDEX l_index.
    l_minus = lt_list-str+20(25).

    l_index = sy-tabix + 1.
    READ TABLE lt_list INDEX l_index.
    l_end = lt_list-str+20(25).

    EXIT.
  ENDIF.
ENDLOOP.

WRITE: / l_start,
       / l_plus,
       / l_minus,
       / l_end.

Новости:

Автор Тема: Вызов транзакции (проги) со своей и последующий забор данных (Прочитано 4813 раз)

Facebook Comments